***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 21, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3409-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.3		 kp = 4.0		)
.model  dds   d(
+   is = 4.316e-10	  n = 1.537		   rs = 2.621e-1
+   eg = 1.182	       trs1 = -7.145e-3)
.model  dbody d(
+   is = 6.316e-10	  n = 1.607		   rs = 2.621e-1
+   eg = 1.182	       trs1 = -7.045e-3
+  cjo = 4.637e-11	  m = 4.366e-1		   vj = 3.905e-1
+   bv = 33		ibv = 250e-6		 tbv1 = 7.498e-4		tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 2.408e-10	  m = 5.286e-1		   vj = 3.905e-1)
.param
+  cgs = 6.053e-10	cgd = 2.397e-10
+   rd = 3.600e-2	 ra = 1.000e-3		  trd = 6.041e-3
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 1.90 ),
+ (2.50 , 2.55 ),
+ (3.00 , 3.15 ),
+ (3.50 , 3.64 ),
+ (4.00 , 4.04 ),
+ (4.50 , 4.40 ),
+ (5.00 , 4.70 ),
+ (6.00 , 5.05 ),
+ (8.00 , 5.55 ),
+ (10.0 , 5.85 ),
+ (20.0 , 6.00 ),
+ (22.0 , 6.10 ))
egt	  1  2t   value = {1.107e-3*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
